Forth

." Hello, world!"

1. 개요

1.1. 명칭

2. 역사

3. 문법

3.1. 사칙연산

2 3 5 * + .

1. 스택에 값을 삽입해 (2, 3, 5)의 값이 있다.
2. 연산자 * 에 의해 스택에는 (2, 15)의 값이 있다.
3. 연산자 + 에 의해 스택에는 (17)의 값이 있다.
4. 명령어 . 에 의해 스택의 가장 위에 있는 값 17이 출력된다. 스택에는 아무 값도 없다.

2 3 + 5 * .

1. 스택에 값을 삽입해 (2, 3)의 값이 있다.
2. 연산자 + 에 의해 스택에는 (5)의 값이 있다.
3. 스택에 값을 삽입해 (5, 5)의 값이 있다.
4. 연산자 * 에 의해 스택에는 (25)의 값이 있다.
5. 명령어 . 에 의해 스택의 가장 위에 있는 값 25가 출력된다. 스택에는 아무 값도 없다.

3.2. 단어

: addprint ( n1 n2 -- n1+n2 )
    + dup .
;

1. : 를 통해 단어를 정의하기 시작한다.
2. 단어의 이름은 addprint이다.
3. 소괄호를 통해 스택의 변화를 주석으로 기술해놓았다.
1. \-\- 앞은 소비할 값, 뒤는 내놓을 값이다.
2. 두 정수 n1과 n2를 소비할 것임을 알려준다.
3. n1과 n2를 더한 값을 내놓을 것임을 알려준다.
4. 단어는 '+ dup .' 의 행동을 취한다.
1. + 연산자를 통해 우선 스택의 두 값을 뽑아 더한다.
2. dup 명령어를 통해 스택의 맨 위에 있는 값, 즉 앞에서 더한 값을 복사해 스택의 맨 위에 추가한다.
3. . 명령어를 통해 스택의 맨 위에 있는 값을 뽑으면서 출력한다. dup을 하였으므로 스택에는 더한 값이 여전히 남았다.
5. ; 를 통해 단어의 정의를 마친다.

3.2.1. 지역변수

: addprint2 { a b -- a+b }
    a .
    '+' emit space
    b .
    ." = "
    a b + dup .
;

1. 중괄호 내에 들어가서 공백으로 구분된 단어들은 지역변수가 될 것이다.
   여기서 a가 먼저 들어간 값, b가 나중에 들어간 값, 즉 스택의 맨 위에 있는 값이다.
   중괄호 안에서 -- 뒤는 주석이다. 스택에 남는 값을 주석으로 기술한다.
2. a 로 지역변수 a의 값을 스택에 넣는다. 이후 . 명령어로 출력했다. 이후 b도 마찬가지로 출력된다.
3. '+' 는 문자 리터럴로 해당하는 문자의 아스키 코드값을 스택에 넣었다.
   이후 emit 명령어로 그 코드에 맞는 문자를 출력한다.
4. space 명령어로 공백 하나를 출력했다.
5. ." 명령어는 공백 이후 " ( 쌍따옴표)까지 올 문자열을 출력한다.
   따라서 "(a의 값) + (b의 값) = "의 문자열이 화면에 출력된다.
6. a b 로 a와 b의 값을 스택에 넣고, 이전처럼 계산해서 출력한다.
   스택에는 a와 b를 더한 값이 남는다.

3.2.2. 반환 스택

: 2swap ( x1 x2 x3 x4 -- x3 x4 x1 x2 )
    rot >r rot r>
;

1. rot으로 스택을 조작해 마지막 3개의 원소의 순서를 회전시켜 (x1, x2, x3, x4)에서 (x1, x3, x4, x2)가 된다.
2. \>r로 반환 스택에 값을 집어넣는다. 스택에는 (x1, x3, x4)가 있고, 반환 스택에는 (x2)가 있다.
3. rot으로 인해 (x1, x3, x4)의 스택이 (x3, x4, x1)이 된다.
4. r>로 반환 스택에서 값을 가져온다. 스택에는 (x3, x4, x1, x2)가 남는다. 의도한 대로 두 쌍의 값들의 위치가 서로 바뀌었다.

3.3. 제어문

3.3.1. 조건문

3.3.1.1. if 문

: max ( n1 n2 -- n )
    2dup
    < if
        drop
    else
        nip
    then
;

1. 2dup 명령어가 스택의 두 원소를 그대로 복제한다.
2. < 를 통해 스택의 윗 값이 더 크면 true, 그렇지 않으면 false가 스택에 남는다.
3. if 는 스택에서 값을 뽑아 참일 때와 거짓일 때를 가려 조건 실행을 한다.
   if 이후 else나 then이 오기 전까지의 코드는 참이면 실행된다.
   참일 경우 drop 명령어를 통해 스택의 맨 윗 값을 버린다.
4. else 이후 then이 오기 전까지의 코드는 거짓일 경우 실행된다.
   이때 else는 꼭 없어도 된다. 거짓일 경우 nip 명령어를 통해 스택의 맨 위에서 바로 아랫 값을 버린다.
5. then으로 조건문을 종료한다. gforth 구현체에선 then 대신 endif를 사용해도 좋고, 오히려 더 권장된다.

3.3.1.2. case 문

case
    1 of ." one" endof
    2 of ." two" endof
    3 of ." three" endof
    2 2 + of ." four" endof
    ." other number"
endcase

3.3.2. 반복문

3.3.2.1. begin~ 문

0
begin
    dup . 1 +
again

0
begin
    dup . 1 +
    dup 10 >
until

0
begin
    1 +
    dup 10 <
while
    dup .
repeat

3.3.2.2. 횟수 반복문

3.3.2.2.1. ?do~ loop 문

10 0 ?do
    i .
loop

0 10 -do
    i .
1 -loop

3.3.2.2.2. for~ next 문

10 for
    i .
next

3.4. 메모리

3.4.1. 전역 변수

variable v
v .
10 v !
v @ .

1. 전역 변수 v를 생성하였다.
2. v를 입력하면 스택에는 전역 변수 v의 주소가 남는다. 온점으로 출력시켰다. 포스에서는 모든 전역 변수를 포인터로 접근하는 셈이다.
3. 10을 v에 저장하였다. 느낌표는 값을 주소에 집어넣는다. C에서의 포인터 대입 연산과 같다.
4. v를 입력하여 스택에 주소를 남긴 다음, 주소에서 값을 가져오는 @을 입력했다. 스택에는 v에 들어간 값인 10이 남는다. 이를 출력하였다.

3.4.2. create와 allot

create arr1 3 cells allot
1 arr1 !
2 arr1 cell+ !
3 arr1 2 cells + !

1. create로 arr1이라는 단어를 생성하였고, 3 셀 만큼의 공간을 할당하였다. 각 공간은 초기화되어있지 않은 상태이다. [?, ?, ?]
2. 1을 arr1의 주소에 저장하였다. 기본적으로 첫 번째 공간을 가리킨다. [1, ?, ?]
3. arr1의 주소에 한 셀 만큼을 더해서 그 주소에 2를 저장하였다. [1, 2, ?]
4. arr1의 주소에 두 셀 만큼을 더해서 그 주소에 3을 저장하였다. [1, 2, 3]

create arr2 1 , 2 , 3 ,

3.4.3. 힙 메모리 할당

10 cells allocate throw
20 cells resize throw
free throw

1. allocate로 10 셀 만큼의 공간으로 동적 할당하였다. throw는 에러 처리를 수행하고, 스택에는 할당한 공간의 시작 주소가 남는다.
2. resize로 20 셀 만큼의 공간으로 해당 주소의 공간을 재 할당하였다. throw는 에러 처리를 수행하고, 스택에는 다시 할당된 공간의 시작 주소가 남는다.
3. free로 주소의 공간을 할당 해제하였다. throw는 에러 처리를 수행한다.

4. 구현체

4.1. GForth

4.2. SwiftForth, SwiftX

4.3. pForth

4.4. 기타 구현체

• SP-Forth: 러시아에서 개발된 구현체.
• Mecrisp: MSP430를 위한 구현체.
• VFX Forth: 고속의 네이티브 코드를 생성하는 구현체.

5. 외부 링크

• https://forth-standard.org/: 포스 표준 홈페이지
• http://theforth.net/: 포스 패키지 저장소
• http://www.forth.org/: 포스 그룹 (Forth Interest Group)
• https://forth-ev.de/: 독일 포스 그룹 (Forth-Gesellschaft e.V.)
• https://forth.hcc.nl/: 네덜란드 포스 그룹 (HCC! Forth)
• http://www.forth.org/svfig/: 실리콘 밸리 포스 그룹 (Silicon Valley FIG)